Fazer um objeto se "reativar" sem perder seus dados

No jogo que estou desenvolvendo tem o "objHUD" que consiste em mostrar a vida e dinheiro do player.

Eu deixo ele como persistente para quando eu mudar de room ele continuar com os valores do player em questão. Porém se meu personagem morre a room é reiniciada, criando assim um novo HUD abaixo do antigo, ficando 2 HUDs sobrepostos.

Eu queria que de alguma maneira, o HUD do player que morreu se "redirecionasse" para o novo player que spawnou. Com isso eu não teria que criar um HUD novo toda vez que o player morresse e poderia deixar o mesmo persistente.

Mas ainda tem um detalhe, se conseguirmos fazer isso acima possível, o player não pode renascer com 0 de vida, ele teria que voltar com pelo menos 1 para se manter vivo e não gerar outro bug.

Eu usava muito o gamemaker a uns anos atrás e estou voltando recentemente na plataforma. Sou beeem fraco na programação em si, mas aprendi bastante desde que eu comecei.
Se puderem me ajudar com esse obstáculo que estou tendo aqui ficarei muito agradecido
Se precisarem dos códigos para facilitar na resolução desse problema, só falar que eu envio aqui.

Poderia colocar o código do teu HUD ?

Posso sim com certeza:

Create

Código:

/// @description Set variables
target = noone;
hp = 0;
max_hp = 0;
hp_flash = 0;
gold = 0;
gold_scale = 1;
gold_scale_target = 1;
gold_flash = 0;
fps_round = 0;
fps_timer = 0;
c_test = c_orange; ///Colour of test text


Step

Código:

// Initialize input variables
var kRestart, kQuit;

kRestart   = keyboard_check_pressed(ord("R"));
kQuit      = keyboard_check_pressed(vk_escape);

// Restart application
if (kRestart)
    room_restart();
    
// Close application
if (kQuit)
    game_end();



End Step

Código:

/// @description Set variables

depth = -1000

var old_gold = gold;
var old_hp = hp;
if (gold_flash > 0)
{
    gold_flash--;
}
if (hp_flash > 0)
{
    hp_flash--;
}

///Update values to display on the HUD
if (target != noone)
{
    if (instance_exists(target))
    {
        hp = target.hp;
        max_hp = target.max_hp;
        gold = target.gold;
    }
    else
    {
        hp = 0; //The target is dead!
        target = noone;
    }
}

///If hp value has decreased, flash the health bar!
if (old_hp != hp)
{
    hp_flash += 4;
}

///If the gold value has increased,
///increase the scale depending on the increase amount
if (old_gold < gold)
{
    gold_scale = min(2, gold_scale+min(0.25, (gold-old_gold)/20));
    gold_flash += 2;
}

///Slowly reduce gold scale back to 1
var k = 0.1;
gold_scale = smooth_approach(gold_scale, gold_scale_target, k);

///Update fps
fps_timer--;
if (fps_timer < 0)
{
    fps_round = round(fps_real);
    fps_timer = 2;
}




Draw

Código:

/// @description Draw HUD
var xx = __view_get( e__VW.XView, 0 )+2;
var yy = __view_get( e__VW.YView, 0 )+2;
///Draw health bar
if (hp_flash > 0)
{
    d3d_set_fog(true, c_white, 1, 0);
}
draw_sprite_healthbar(xx, yy, 5, sprHeartIcon, hp, max_hp);
if (hp_flash > 0)
{
    d3d_set_fog(0, 0, 0, 0);
}
///Draw gold
yy += 16+((9*((max_hp-1)/2 div 5)+1));
draw_set_font(font0);
draw_set_halign(fa_left);
draw_set_valign(fa_middle);
var str = string(gold)+"g";
if (gold_flash > 0)
{
    draw_set_colour(c_white);
}
else
{
    draw_set_colour(c_black);
}
draw_text_transformed(xx+0, yy, string_hash_to_newline(str), gold_scale, gold_scale, 0);
draw_text_transformed(xx+2, yy, string_hash_to_newline(str), gold_scale, gold_scale, 0);
draw_text_transformed(xx+1, yy-1, string_hash_to_newline(str), gold_scale, gold_scale, 0);
draw_text_transformed(xx+1, yy+1, string_hash_to_newline(str), gold_scale, gold_scale, 0);
if (gold_flash > 0)
{
    draw_set_colour(c_white);
}
else
{
    draw_set_colour(c_yellow);
}
draw_text_transformed(xx+1, yy, string_hash_to_newline(str), gold_scale, gold_scale, 0);
draw_set_colour(c_white);
///Draw test stuff
if (global.test_mode)
{
    yy += 14;
    draw_text_outlined(xx+1, yy, string(fps_round), c_test, c_black);
    yy += 14;
    draw_text_outlined(xx+1, yy, "Entities: "+string(instance_number(objEntity)), c_test, c_black);
}






Alguém ai de sabedoria infinita poderia me dar uma mãozinha com isso?

Quando a room reinicia tem algum código que faz o HUD de hp ser criado novamente é? ou so tem o codigo de reiniciar?

Coloque no Room Start do seu objHUD:

Código:

target = instance_find(objPlayer, 0);

E não coloque os objetos em questão como persistentes.

Resolveu Pedrox! Brigadão

O objHUD era criado a partir do objLevel, ele criava alguns outros objs de controle da room, ai eu tirei e coloquei o objHUD na propria room com esse código.

Funcionou perfeito! Eu tinha esquecido completamente desse "instance_find".

E realmente, eu não devo deixa-lo persistente, me toquei depois que o hud ele tira os status do próprio player e não dele mesmo kkkkk brigadão, irmão.