[Resolvido]Problemas com movimentação básica

Eu não sei exatamente o que é, mas o que eu sei é que uma parte do objeto do jogador, quando cai, fica preso ao objeto de colisão, e então eu não consigo ativar nenhum movimento.
########################################################
/////Keys
right = keyboard_check(vk_right);
left = keyboard_check(vk_left);
jump = keyboard_check(ord('Z'));
////movements
///Walk
if left{
   hspeed = 3;
   if place_meeting(x + 1, y, obj_collisionbox){
       hspeed = +0;
   }
}
else
if left{
   hspeed = -3;
   if place_meeting(x - 1, y, obj_collisionbox){
       hspeed = -0;
   }
}
else
hspeed = hspeed / 2;
////Collision
if !jump and place_meeting(x, y - 1, obj_collisionbox){
   vspeed = 0;
}
else
if jump and  not place_meeting(x, y - 1, obj_collisionbox){
   vspeed = -10 / 2;
}
else
if !jump and not place_meeting(x, y - 1, obj_collisionbox){
   if vspeed < 0{
       vspeed = vspeed / 2
   }
   if vspeed  = 0{
       vspeed = 2;
   }
}

O problema pode ser na mascara de colisão do sprite

Infelizmente, o sistema de colisão do GM é meio bugado. Eu sempre recomendo fazer o próprio sistema de movimentação ao invés de utilizar as funções nativas (no seu caso, hspeed, vspeed e gravity). Prefira utilizar x/y no lugar.

Bom, de todo modo, olhando pro código que você mandou, antes de cada movimento você verifica se há espaço para andar e pular, mas, em nenhum momento você verificou se há espaço para cair. Algo desse tipo talvez resolva:

Código:

if (vspeed > 0 && place_meeting(x, y + vspeed, obj_collisionbox)
    vspeed = 0;

Obs.: Esse código talvez não tenha um efeito legal. Considere minhas recomendações acima!

Sobre o restante do seu código, algumas observações:
1 - Você está checando se a variável left é true para poder ir pra direita.
Acho que foi só um erro de digitação, mas corrige lá!
2 - Você usa hspeed 3, mas verifica se tem 1px livre pra andar. Haverá casos em que o seu objeto estará à 2px de distancia do bloco, irá se movimentar 3px e ficará 1px a frente do bloco, e, muito provavemente, vai grudar nele. Talvez resolva com o mesmo codigo que usei no exemplo acima, ficando assim:

Código:

if left{
  hspeed = -3;
  if place_meeting(x - hspeed, y, obj_collisionbox){
      hspeed = -0;
  }
}

Qualquer dúvida é só falar!

Boa tarde! Agora estou tendo dois problemas com a colisão do objeto:
1 - Quando eu colido na direita, o jogador prende na parede e eu só consigo pular. Na esquerda, parte do sprite do jogador entra na parede e eu não consigo me mover e nem pular;
2- Quando eu pulo e o jogador bate em uma parede acima dele, o sprite também prende, o que faz com que eu não consiga me mover nem pular.
##################################
Eu não sei se realmente é problema na mask do sprite mas aqui estão as configurações dos objetos do jogador e da caixa de colisão:
mask do jogador: 10 x 16, origin: x = 0; y = 0;
caixa de colisão: 16 x 16, origin: x = 0; y = 0;
###################################
O cógido com algumas alterações de acordo com a ajuda:

Código:

/////Keys
right = keyboard_check(vk_right);
left = keyboard_check(vk_left);
jump = keyboard_check_pressed(ord('Z'));
////movements
///Walk
if right{
   hspeed = 3;
   if place_meeting(x + hspeed, y, obj_collisionbox){
       hspeed = 0;
   }
}
else
if left{
   hspeed = -3;
   if place_meeting(x - hspeed, y, obj_collisionbox){
       hspeed = -0;
   }
}
else
hspeed = 0;
////Jump
if !jump and place_meeting(x, y - vspeed, obj_collisionbox){
   vspeed = 0;
}
else
if jump and  not place_meeting(x, y - vspeed, obj_collisionbox){
   vspeed = -20 / 2;
}
else
if !jump and not place_meeting(x, y - vspeed, obj_collisionbox){
   if vspeed < 0{
       vspeed = vspeed / 2
   }
   if vspeed  = 0{
       vspeed = 2;
   }
}
if vspeed > 0 and place_meeting(x, y + vspeed, obj_collisionbox){
    vspeed = 0;
}

Como o @Willy falou, usar hspeed, vspeed e gravity é meio arriscado por ser um sistema que temos menos controle das interações, ficando bem mais propenso a bugs, eu tentei usar seu código e apareceu o mesmo problema para mim, o que é estranho, realmente deveria estar funcionando(ao menos as colisões horizontais), tentei usar outra lógica para a movimentação sem bagunçar muito o que você tem.

Fiz alguns testes e modifiquei um pouco o seu walk, com isso já não acontece mais o bug:

Código:

//Walk
var dir;
dir = right - left;
hspeed = 0;

if (dir != 0){
  hspeed = dir * 3;
  if (place_meeting(x + hspeed, y, obj_collisionbox))
    hspeed = 0;
}

Uma versão com a colisão melhorada(mais precisa), quando chega perto da parede, nós aproximamos o personagem unidade por unidade com o sign:

Código:

//Walk
var dir;
dir = right - left;
hspeed = 0;

if (dir != 0){
  hspeed = dir * 3;
  if (place_meeting(x + hspeed, y, obj_collisionbox)){
    while (!place_meeting(x + sign(hspeed), y, obj_collisionbox))
      x += sign(hspeed);
    hspeed = 0;
  }
}

Quanto ao jump, a quantidade de checagens acabavam por complicar muito, acabei mudando bem mais o código, mas seguindo a base lógica que usei para a movimentação horizontal;

Código:

//Jump
vspeed += .6;

if (jump && place_meeting(x, y + 1, obj_collisionbox))
  vspeed = - 10;

if (place_meeting(x, y + vspeed, obj_collisionbox)){
  while(!place_meeting(x, y + sign(vspeed), obj_collisionbox))
    y = y + sign(vspeed);
  vspeed = 0;
}

Note que o ".6" seria o valor equivalente para a gravidade, e que o -10 é a força do jump.
Você ainda vai precisar de algumas alterações nesses valores, mas creio que isso é só questão de fazer testes.