como substituir o keyboard_wait??

A situação difícil é a seguinte: aparece uma imagem, que deve desaparecer se o jogador aperta uma tecla OU se passarem 10 segundos: O QUE VIER PRIMEIRO!!

Por que o problema? Porque não consigo contar 10 segundos ao mesmo tempo que o keyboard_wait estiver ativo, porque TUDO PARA! - inclusive alarms, e medida de current_second, o que eu quiser inventar para ver se passaram ou não os tais dez segundos...

Alguém, por favor , tem alguma idéia salvadora??

Thanks A LOT!!

faz assim entao, em vez de keyboard_wait, usa if (keyboard_check(vk_anykey))

O melhor é vc cirar um objeto mostrador de imagens. Ai neste objeto você colocar um código nele:
obMensagem:
Evento Create:

Código:


alarm[0] = room_speed * 10; // 10 segundos


Evento Step:

Código:


if keyboard_check(vk_anykey) instance_destroy();


Evento Alarm[0]:

Código:


instance_destroy();


Evento Draw()

Código:


draw_text(x, y, mensagem);


Ai é so vc criar este objeto quando for exibir sua mensagem:

Código:


in = instance_create(10, 10, obMensagem);
in.mensagem = "Minha Mensagem";


Lembrando que vc pode melhorar o evento Draw do objeto obMensagem pra colocar um box na mensagem. Esse objeto pode ser usado sempre que vc for exibir uma mensagem. E não se esqueça de colocar o depth dele como -1

iara escreveu:A situação difícil é a seguinte: aparece uma imagem, que deve desaparecer se o jogador aperta uma tecla OU se passarem 10 segundos: O QUE VIER PRIMEIRO!!

Por que o problema? Porque não consigo contar 10 segundos ao mesmo tempo que o keyboard_wait estiver ativo, porque TUDO PARA! - inclusive alarms, e medida de current_second, o que eu quiser inventar para ver se passaram ou não os tais dez segundos...

Alguém, por favor , tem alguma idéia salvadora??

Thanks A LOT!!

No Draw da instância responsável pelo desenho dessa imagem, defina a condição de desenho:

Código:

if imagem = true then draw_sprite(imagem,sub-imagem,x,y)

Se você estiver usando a função show_image, esqueça. Essa rotina é usada pelo Windows e não pelo GM, o que deixa o handle da janela do jogo em segundo plano, atrapalhando tudo.

No evento Create da mesma instância digite:

Código:

imagem = true;
tempo = 0;

No evento Step da mesma instância digite:

Código:

if (imagem = true) and (tempo < 10) then
    begin
          tempo += 1/room_speed;
          if keyboard_check(vk_anykey) then imagem := false;
    end;

Boa sorte! =]

Não sei por que o keyboard_check não funciona. Tive que usar o keyboard_check_direct, e assim mesmo, ele só aceita o mouse. Juro que não entendo! :-((
recebi uma sugestão e fiz assim:
{io_clear();

// apresenta objeto

draw_set_color(c_white);
draw_set_halign(fa_center);
draw_text ( room_width/2, room_height/2, string(obj));
screen_refresh();

// loop de contagem do tempo
inicio = current_time;
while( (current_time-inicio) < 10000)&& !(keyboard_check_direct(vk_anykey))
{tp = current_time-inicio};
loop = current_time-inicio;
tecla = keyboard_lastkey;



//teste
if tp >= 10000 show_message("acabou o tempo: "+ string(loop))else show_message("tempo de resposta = "+string(tp)+" tecla acionada = "+string(tecla));

}

Por que será que só responde ao mouse??
Será que é porque meu teclado é wireless? Mas o mouse tb é!! E agora?

A solução do vinians, para mim, tem o problema (desculpem, não tinha dito) de que quero que o tempo entre a tecla e o desenho da imagem interfira o mínimo possível com o tempo de resposta. Esperar eventos aumenta o tempo.

Obrigada a todos pelas sugestões!

Acho que entendi o que você quer. Tipo, declare uma variável no objeto que controlará tudo isso:

Código:


imagem=1;
alarm[0]=10*room_speed;


Perceba que setamos o alarm para 10 * room_speed. Em 10, coloque os segundos que vc quer. Aí, precisamos criar um evento alarm0, para quando tiver passado 10 segundos, parar de desenhar a imagem:

Código:


imagem=0;


Agora, no Step, você precisa checar se alguma tecla está sendo apertada. Para isso, podemos usar o vk_anykey, que funciona igual ao vk_left, vk_right e outros eventos de teclas. A diferença é que ele vale para TODAS as teclas:

Código:


if (keyboard_check(vk_anykey))
{
imagem=0;
}


A parte importante já está feita. Agora, basta desenhar o sprite no local desejado, caso a variável imagem seja "1". Para isso, use o evento Draw:

Código:


if (imagem==1)
{
draw_sprite(spr_nome_do_sprite,sub_imagem,posicaox,posicaoy);
}


Se a imagem não for animada (tiver vários frames), coloque 0 em sub_imagem.

iara escreveu:Tive que usar o keyboard_check_direct, e assim mesmo, ele só aceita o mouse.

Você está usando a função show_image()? Se estiver usando-a, qualquer dos códigos acima deixarão de funcionar porque essa é uma rotina do Windows e não do Game Maker. Nesse caso você deve substití-la por draw_sprite, draw_sprite_ext, draw_background, etc.... ou seja, qualquer função de desenho dentro do Game Maker.

Algumas dicas:

iara escreveu:

Código:

// apresenta objeto

draw_set_color(c_white);
draw_set_halign(fa_center);
draw_text ( room_width/2, room_height/2, string(obj));
screen_refresh();

iara, nesse caso a função screen_refresh() pode atrapalhar, principalmente se estiver dentro de um evento Draw. Só usamos essa função dentro de loops.

Veja que você definiu um while para que a variável tp seja sempre menor que 10000, no "(current_time-inicio) < 10000".

iara escreveu:

Código:

// loop de contagem do tempo
inicio = current_time;
while( (current_time-inicio) < 10000)&& !(keyboard_check_direct(vk_anykey))
{tp = current_time-inicio};
loop = current_time-inicio;
tecla = keyboard_lastkey;

Aqui, a condição de tp ser maior ou igual à 10000 é impossível, e somente o else vai funcionar:

iara escreveu:

Código:

//teste
if tp >= 10000 show_message("acabou o tempo: "+ string(loop))else show_message("tempo de resposta = "+string(tp)+" tecla acionada = "+string(tecla));

Este código aqui funcionou, finalmente, e me foi enviado por Pedro Osório, nosso colega de Portugal

Código:

io_clear();
 // apresenta objeto
 
 draw_set_color(c_white);
 draw_set_halign(fa_center);
 draw_text ( room_width/2, room_height/2, string(obj));
 screen_refresh();
 
 // loop de contagem do tempo
 inicio = current_time;
 while( (current_time-inicio) < 10000) && !(keyboard_check(vk_anykey))
      {
      sleep(50); //Para que o programa não use todos os recursos do PC, assim ele verifica o teclado de 50ms em 50ms
      };
 tp = current_time-inicio;
 tecla = keyboard_lastkey;
 
 
 
 //teste
 if tp >= 10000 show_message("acabou o tempo: "+ string(tp))else show_message("tempo de resposta = "+string(tp)+"  tecla acionada = "+string(tecla));




Outra opção que o Pedro Osório me deu foi o uso de alarmes, assim:

Evento create:

Código:

 alarm[0]=10*room_speed; //Definir o alarme para daqui a 10 segundos
 inicio=current_time;

Evento Alarm:

Código:

//O alarme foi activado, ou seja, acabou o tempo
tp=current_time-inicio;
show_message("acabou o tempo: "+ string(tp));
instance_destroy();

Evento Step:

Código:

if (keyboard_check(vk_anykey)) {
    //Alguma tecla foi pressionada, mostramos a mensagem e destruímos a instância
    tp = current_time-inicio;
    tecla = keyboard_lastkey;
    show_message("tempo de resposta = "+string(tp)+"  tecla acionada = "+string(tecla));
    instance_destroy();
}



Evento DRAW:

Código:

// Mostrar o obj
 draw_set_color(c_white);
 draw_set_halign(fa_center);
 draw_text ( room_width/2, room_height/2, string(obj));

Ficam aí as sugestões do nosso amigo da extinta comunidade portuguesa, para quem mais precisar