[Resolvido]Como fazer o tiro sair da arma em um jogo tds

Estou com o seguinte problema, estou fazendo um jogo top down shooter onde o personagem sempre olha para o mouse, e centralizei meu personagem na sprite para ele girar no proprio eixo, só que após implementar o sistema de tiro, os tiros estão saindo pelo centro do personagem, e não quero centralizar a sprite na arma porque se girar o mouse o personagem vai girar no eixo da arma e fica feio e estranho além de bugado

Código:

var click = mouse_check_button_pressed(mb_left);
var click2 = keyboard_check_pressed(ord("R"));
var lenx = x+lengthdir_x(100, image_angle)
var leny = y+lengthdir_y(100, image_angle)


if(click && parado == spr_pistola_parado && andando == spr_pistola_andando && global.pistola_municao > 0 && atirar = true){
    with(instance_create(lenx,leny,obj_bala)){
    speed = 30
    direction = other.image_angle + random_range(-4, 4);
    image_angle = direction
    }
    sprite_index = spr_pistola_atirando
    andando = spr_pistola_atirando
    global.pistola_municao -= 1
    atirar=false
    alarm[0] = delay;
}

esse é o codigo que estou utilizando para atirar, estou aceitando qualquer ajuda e sugestão

Qual versão do Game Maker você está usando?

Nas versões mais recentes não se usa mais o "instance_create", usa-se o "instance_create_layer" ou "instance_create_depth".

Mas pelo que parece a lógica do seu código está correta.

Código:


var lenx = x+lengthdir_x(100, image_angle);
var leny = y+lengthdir_y(100, image_angle);


Aquele valor "100" no trecho de código acima é a distância do centro do objeto player que a bala será criada, na teoria essa distância deve ser o número de pixels desde o centro do sprite do seu objeto player até a ponta da arma onde a bala deve sair, na prática, pode ser que esse numero precise ser menor visto que já no primeiro step a bala vai viajar com 30 speed ai pode dar a impressão que a bala já saiu muito longe do player, isso ai se ajusta testando.

A origem do objeto bala deve ser observada também, pode ser que a origem tenha que ser na parte de trás central da bala e não justamente no centro da sprite da bala, mas isso aí depende de como é o sprite bala do seu projeto.

Para ver onde esta sendo a origem da sua bala em relação ao player adicione o seguinte código no evento draw do seu objeto player:

Código:



draw_self();

var bulletX = x + lengthdir_x(100, image_angle);
var bulletY = y + lengthdir_y(100, image_angle);
 
draw_set_color(c_red);
draw_circle(bulletX, bulletY, 5, false);



Assim o Game Maker vai desenhar um pequeno círculo vermelho onde está sendo a origem do seu objeto bala e você pode conferir visualmente.


Em um pequeno teste que fiz aqui, usei o seguinte código no evento step do objeto player e funcionou:

Código:

image_angle = point_direction(x, y, mouse_x, mouse_y);

if mouse_check_button_pressed(mb_left){
 
 var bulletX = x + lengthdir_x(sprite_width/2, image_angle);
 var bulletY = y + lengthdir_y(sprite_height/2, image_angle);
 
 instance_create_layer(bulletX, bulletY, "Instances", oBullet,{
 speed: 30,
 direction: image_angle + random_range( -4, 4),
 image_angle: image_angle
 });
 
}

É a mesma logica do seu código, porém sem os filtros, e a forma de passar as informações iniciais para o objeto bala também é um pouco diferente, mas essa forma só funciona nas versões mais recentes do GameMaker, que é por meio de uma struct.

A qualquer duvida estou a disposição, abraços!

Realmente funcionou, me ajudou muito, obrigado mesmo de verdade